#!/bin/sed -f
# egroups-kill-sig.sed - erases egroups.com e-mail signature
# 20000??? <aurelio@conectiva.com.br> v0.1
# 20000725 <aurelio@conectiva.com.br> v0.2
# 20000906 <aurelio@conectiva.com.br> v0.3
# 20001107 <aurelio@conectiva.com.br> v0.3.1 (schlemer HTML killer)

###########################################################################
# DESCRIPTION:
# egroups.com puts advertises on every sent message to the free groups.
# here's a sed 1liner to erase it. just put it on your ~/.procmailrc
# and no more egroups signature at the messages.
#
# at the begin of your ~/.procmailrc, put:
#    :0 fhbw
#    * Delivered-To:.*@egroups.com
#    | sed 'the-cool-sed-rule-below'
#
###########################################################################
#
# so, here we go
#
#
#    THE VICTIM: the 1st egroups signature
#       details: * a line with exactly 72 hifens before and after
#                * any number of lines between
#                * a line with 'http://click.egroups.com'
#
# ------------------------------------------------------------------------
# $60 in FREE Long Distance!  Click Here to join beMANY! today.
# http://click.egroups.com/1/4126/10/_/_/_/958599956/
# ------------------------------------------------------------------------
#
#     THE KILLER: our macho sed big 1liner
#
#/^\(> \)*-\{72\}$/{N;:l;/-\{72\}$/bs;N;bl;:s;s%^.*\n\(> \)*http://click\.egroups\.com.*%%;}
#
###########################################################################
#
# but it's now (20000725) has changes to something easier.
#
#
#    THE VICTIM: egroups actual signature
#       details: * a line with 68 hifens, an '<e|' and another hifen
#                * lines with egroups propaganda
#                * a line with 68 hifens, an '|e>' and another hifen
#
# --------------------------------------------------------------------<e|-
# Huge Shoe Selection at Zappos.com
# (small sizes also available)
# http://click.egroups.com/1/7062/5/_/193628/_/964577029/
# --------------------------------------------------------------------|e>-
#
# THE KILLER: our macho sed 1liner
#
#/^\(> \)*-\{68\}<e|-$/,/^\(> \)*-\{68\}|e>-$/d
#
###########################################################################
#
# again, egroups changed (20000830) the rules, so change our sed.
#
#    THE VICTIM: egroups actual signature
#       details: * a line wih 26 hifens, 'eGroups Sponsor', 25 hifens and '~-~>'
#                * lines with egroups propaganda
#                * a line with 69 hifens, and '_->' at the end
#
# -------------------------- eGroups Sponsor -------------------------~-~>
# GET A NEXTCARD VISA, in 30 seconds!  Get rates
# of 2.9% Intro or 9.9% Ongoing APR* and no annual fee!
# Apply NOW!
# http://click.egroups.com/1/7872/14/_/_/_/967638075/
# ---------------------------------------------------------------------_->
#
# THE KILLER: our macho sed 1liner
#
/^\(> \)*-\{26\} eGroups Sponsor -\{25\}~-~>$/,/^\(> \)*-\{69\}_->$/d

#
# and now (20001107) a contribution from elgio schlemer, for those who
# receive the egroups messages in HTML (argh!), because the signature
# is way different.
#
#    THE VICTIM: egroups actual HTML signature
#       details: * an HTML comment with bar-star-star-bar,text,bar-star-star-bar
#                * lines with egroups propaganda
#                * an HTML comment with bar-star-star-bar,text,bar-star-star-bar
#
# <!-- |**|begin egp html banner|**| -->
#
# <hr>
# <!-- |@|begin eGroups banner|@| runid: 8193 crid: 4101 -->
# <a target=3D"_blank"
# href=3D"http://click.egroups.com/1/8193/8/_/134812/_/9=
# 66089206/"><center>
# <img width=3D"468" height=3D"60"
#   border=3D"0"
#   alt=3D""
# src=3D"http://adimg.egroups.com/img/8193/8/_/134812/_/966089206/468x60_ma=
# ze12k.gif"></center><center><font color=3D"black"></font></center></a>
# <!-- |@|end eGroups banner|@| -->
# <hr>
#
# <!-- |**|end egp html banner|**| -->
#
# THE HTML KILLER: our macho sed 1liner
#
#/^\(> \)*<!-- |\*\*|begin egp html banner|\*\*| -->$/,/^\(> \)*<!-- |\*\*|end egp html banner|\*\*| -->$/d